*Feb 18, 2013
*ECN S13-0378, Rev. C
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet.  Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT SUM55P06-19L 4 1 2
M1  3 1 2 2 PMOS W=6525734u L=0.25u         
M2  2 1 2 4 NMOS W=6525734u L=0.45u  
R1  4 3     RTEMP 12E-3
CGS 1 2     2600E-12
DBD 4 2     DBD
***************************************************************  
.MODEL  PMOS       PMOS  ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 1E-3            RD     = 0           NSUB   = 1.3E17
+ KP     = 2.5E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 6.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS       NMOS  ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 3E16            NFS    = 1E12        TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=500E-12 VJ=0.38 M=0.35
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=60.2)
*************************************************************** 
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS
