*Jan 2, 2006
*Doc. ID: 77720, S-52633, Rev. A
*File Name: Si1499DH_PS.txt and Si1499DH_PS.lib
.SUBCKT Si1499DH 4 1 2
M1  3 1 2 2 PMOS W=449404u L=0.25u 
M2  2 1 2 4 NMOS W=449404u L=1.40u  
R1  4 3     RTEMP 33E-3
CGS 1 2     280E-12
DBD 4 2     DBD
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3            TOX    = 1.3E-8
+ RS     = 15E-3           RD     = 0            NSUB   = 1E15   
+ KP     = 1.16E-5         UO     = 400 
+ VMAX   = 0               XJ     = 5E-7         KAPPA  = 2E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
***************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3            TOX    = 1.3E-8
+NSUB    = 2.7E16          TPG    = 1)   
***************************************************************** 
.MODEL DBD D (CJO=230E-12 VJ=0.38 M=0.39
+RS=1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=8.5)
***************************************************************** 
.MODEL RTEMP RES (TC1=5E-3 TC2=5.5E-6)
***************************************************************** 
.ENDS