*Jan 2, 2006
*Doc. ID: 77754, S-52575, Rev. B
.SUBCKT SiE802DF D G S
M1  3 G S S NMOS W=14612968u L=0.25u  
M2  S G S D PMOS W=14612968u L=0.20u   
R1  D 3     RTEMP 8E-4
CGS G S     4600E-12
DBD S D     DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 5E-8
+ RS     = 6.5E-4          RD     = 0        NSUB   = 2.9E17  
+ KP     = 1.44E-5         UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 5E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5     TCV    = 3.6E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 5E-8
+NSUB    = 6E16            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=2000E-12 VJ=0.38 M=0.27
+RS=0.01 FC=0.1 IS=1E-12 TT=2.8E-8 N=1 BV=30.2)
************************************************************ 
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
************************************************************  
.ENDS