*June 12, 2006
*Doc. ID: 79614, S-60992, Rev. A
*File Name: SiE810DF_PS.txt and SiE810DF_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiE810DF D G S
M1  3  GX S S NMOS W=14612968u L=0.25u
M2  S  GX S D PMOS W=14612968u L=0.25u 
RG  G  GX     0.90
R1  D  3      RTEMP 6.2E-4
CGS GX S      9200E-12
DBD S  D      DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 3E-8
+ RS     = 4E-4            RD     = 0        NSUB   = 3.5E17  
+ KP     = 2.36E-5         UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 1E-5
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 3E-8
+NSUB    = 6E16            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=2000E-12 VJ=0.38 M=0.22
+RS=0.01 FC=0.1 IS=1E-12 TT=2.17E-8 N=1 BV=20.2)
************************************************************ 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
************************************************************  
.ENDS