*October 16, 2006
*Doc. ID: 79795, S-62042, Rev. A
*File Name: SiE812DF_PS.txt and SiE812DF_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiE812DF D G S
M1  3  GX S S NMOS W=14612968u L=0.25u   
M2  S  GX S D PMOS W=14612968u L=0.20u   
RG  G  GX     1.15
R1  D  3      RTEMP 8E-4
CGS GX S      5900E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 11.5E-4         RD     = 0           NSUB   = 2E17   
+ kp     = 9.5E-6          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 2.5E16          TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=2200E-12 VJ=0.38 M=0.36
+FC=0.1 IS=1E-12 TT=2.62E-8 N=1 BV=42)
**************************************************************** 
.MODEL RTEMP RES (TC1=10E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS