*December 11, 2006
*Doc. ID: 79861, S-62485, Rev. A
*File Name: Si7230DN_PS.txt and Si7230DN_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7230DN D G S
M1  3  GX S S NMOS W=3062590u L=0.25u 
M2  S  GX S D PMOS W=3062590u L=0.25u  
RG  G  GX     1.8
R1  D  3      RTEMP 3.8E-3
CGS GX S      1000E-12
DBD S  D      DBD
************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 3.8E-3         RD     = 0           NSUB   = 3.2E17  
+ KP     = 1E-5           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 1E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0            
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 5E16           IS     = 0           TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=500E-12 VJ=0.38 M=0.30
+FC=0.5 EG=1.17 TT=5E-8 T_MEASURED=25 BV=30.5 
+IS=1.156e-10 RS=6.324e-03 N=1.231
+XTI=2.346 TRS1=2.045e-03)
*************************************************************** 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS