*February 26, 2007
*Doc. ID: 79913, S-70349, Rev. A
*File Name: Si1473DH_PS.txt and Si1473DH_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si1473DH D G S
M1  3  GX S S PMOS W=830000u L=0.25u            
M2  S  GX S D NMOS W=830000u L=0.35u    
RG  G  GX     9.2
R1  D  3      RTEMP 46E-3
CGS GX S      240E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 5E-8
+ RS     = 29E-3           RD     = 0          NSUB   = 1.3E17
+ KP     = 3.9E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 2E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 5E-8
+NSUB    = 6E16            IS     = 0  	       TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=60E-12 VJ=0.38 M=0.34
+FC=0.5 TT=1.45E-8 T_MEASURED=25 BV=32
+RS=2.615e-02 N=1.166 IS=9.086e-12 IKF=100
+EG=1.141 XTI=2.855 TRS1=3.312e-03)
*************************************************************** 
.MODEL RTEMP RES (TC1=6.5E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS