*************************************************
* Copyright 2020 © Vishay Intertechnology, Inc. *
* All rights reserved.                          *
*************************************************
*Apr 10, 2021
*DD Vishay semiconduttori italiana SPA
*davide.dapra@vishay.com
*File Name: SMBG40CA.txt
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.


*Model fit device at 25°C
*DEVICE=SMBG40CA,X

**************************************************** 

.SUBCKT SMBG40CA 1 2
* Forward
DF 9 90 DFMOD 
.MODEL DFMOD D N = 2 IS = 5E-008 RS = 0.00786261
+ EG = 1.11 XTI = 3
+ CJO = 2.9E-010 VJ = 3.87125 M = 0.6 FC = 0.5
+ TT = 1E-008
* Leakage
RLF 9 90 4E+007 
RLR 1 9 4E+007 
 * Breakdown
RBD 90 4 2.6344
EBD 4 3 10 20 1
DBD 3 9 DBDMOD 
* Reverse
DR 9 1 DFMOD
RBDR 1 94 2.6344
EBDR 94 93 10 20 1
DBDR 93 9 DBDMOD
.MODEL DBDMOD D IS = 1E-015 N = 0.5 
IBVC 0 10 0.001
RBVC 10 0 40110 TC1 = 0.00099 
RBDX 20 23 2.6344
DBVC 23 22 DBDMOD 
DBVF 22 0 DFMOD 
IBVD 0 20 0.001
*Stray inductance for current return under device
L1 90 2 7.13E-010
.ENDS