*************************************************
* Copyright 2020 © Vishay Intertechnology, Inc. *
* All rights reserved.                          *
*************************************************
*May 7, 2021
*DD Vishay semiconduttori italiana SPA
*davide.dapra@vishay.com
*File Name: SMA6F12A.txt
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.


*Model fit device at 25°C
*DEVICE=SMA6F12A,X

**************************************************** 

.SUBCKT SMA6F12A 9 2
* 9 anode 2 cathode
*Forward
DF 9 90 DFMOD
.MODEL DFMOD D
+ IS=181.51E-15
+ N=1.1027
+ RS=18.343E-3
+ IKF=10.986
+ EG = 1.11 XTI = 3
+ CJO=1.2221E-9 M=2.0798 VJ=17.982
+ ISR=68.937E-9
+ FC = 0.5
+ TT=5.0000E-9
* Leakage
* RL 9 90 leakage from DF junction
* Breakdown
RBD 90 4 0.128
EBD 4 3 10 20 1
DBD 3 9 DBDMOD 
.MODEL DBDMOD D IS = 1E-016 N = 0.5  ISR=6.85E-9
IBVC 0 10 0.001
RBVC 10 0 14000 TC1 = 0.00083
RBDX 20 23 0.128
DBVC 23 0 DBDMOD
IBVD 0 20 0.001
*Stray inductance for current return under device
L1 90 2 3.4E-10

.ENDS